Table of Contents
ugBASIC User Manual
PURPOSE
SOURCE CODE
DEFINE STRING SPACE 128
DEFINE STRING COUNT 32
DEFINE SCREEN MODE UNIQUE
BITMAP ENABLE(16)
CONST step = 2
CONST levels = SCREEN HEIGHT / 16
CONST screenLimitH = ( SCREEN HEIGHT - 1 )
CONST screenLimitH2 = screenLimitH - 16
CONST screenLimitW = ( SCREEN WIDTH - 1 )
CONST screenLimitBH = ( SCREEN HEIGHT - 12 )
CONST screenLimitBW = ( SCREEN WIDTH - 8 )
CONST screenLimitBWB = ( SCREEN WIDTH - 16 )
CONST screenLimitL = 2*step
CONST maxDistancePerPath = 300
CONST startPosX = ( SCREEN WIDTH / 2 ) - 4
CONST maxBallPerGame = 10
CONST centerScreenY = SCREEN ROWS / 2
CONST currentBallsX = SCREEN COLUMNS - 10
DIM x%, y%, px%, py%, dx%, dy%, d@, m@, v@, currentballs@, oldballs@, winColor@
DIM score%, oldscore%,distance%, bx%, by%
GLOBAL x, y, px, py, f, dx, dy, d, m, v, score, oldscore, currentballs, oldballs, distance
GLOBAL winColor, blockColor
GLOBAL bx, by
GLOBAL ball, bar, bgball
GLOBAL basket
PROCEDURE home1
LOCATE , 1
END PROCEDURE
PROCEDURE clrline1
WAIT 1000 MS
LOCATE ,1: CENTER " "
END PROCEDURE
PROCEDURE center
LOCATE , centerScreenY
END PROCEDURE
PROCEDURE titleScreen
CLS
LOCATE , centerScreenY
INK BLUE
CENTER "{BLUE}10 BALLS DOWN!"
CENTER "{GREY}(press fire)"
PRINT
CENTER "{RED}last score: "+STR(score)
WAIT KEY OR FIRE RELEASE
END PROCEDURE
PROCEDURE prepareGraphics
bgball := NEW IMAGE(16,10)
CLS BLACK
INK GREY
BAR 0,0 TO 15,3
INK BLUE
DRAW"L16R2U3L2R16L2D3L4U3L3D3"
bar := NEW IMAGE(16,4)
GET IMAGE bar FROM 0, 0
CLS
INK GREY
BAR 0,0 TO 15,7
INK BLUE
DRAW"BU8D8L15U8"
basket := NEW IMAGE(16,8)
GET IMAGE basket FROM 0, 0
winColor = POINT(3,1)
CLS
INK RED
CIRCLE 4,4,4
PAINT(4,4)
INK WHITE
DRAW"BU2L1D1L1D1"
ball := NEW IMAGE(16,10)
GET IMAGE ball FROM 0, 0
CLS
GET IMAGE bgball FROM 0, 0
END PROCEDURE
PROCEDURE drawBarrier
bx = 0
j = RND(255): i = j: c = 0
REPEAT
IF (j AND 1) = 1 THEN
PUT IMAGE bar AT bx, by
INC c
ENDIF
j = j \ 2
IF ( j = 0 AND c > 4 ) THEN
j = i AND 127
ENDIF
ADD bx, 16
UNTIL bx > screenLimitBW
END PROCEDURE
PROCEDURE drawBarriersAndBaskets
CLS
RANDOMIZE TIMER
by = 24
REPEAT
drawBarrier[]
ADD by, 16
UNTIL by > screenLimitH2
bx = 8
REPEAT
PUT IMAGE basket AT bx, by
ADD bx, RND(16)
ADD bx, 20
UNTIL bx > screenLimitBWB
INK BLUE
DRAW 0,16 TO 0,screenLimitH
DRAW 0,screenLimitH TO screenLimitW,screenLimitH
DRAW screenLimitW,16 TO screenLimitW,screenLimitH
END PROCEDURE
PARALLEL PROCEDURE moveBall
REPEAT
WAIT WHILE d
IF dy OR dx THEN
x3 = x-3: x4 = x+4: y9 = y+9
x9 = x+9: y4 = y+4
IF POINT(x4,y9) = BLACK THEN
dy = 1
dx = 0
ELSE
dy = 0
IF dx = 0 AND y < screenLimitBH THEN
IF RND(100) > 50 THEN
dx = step
ELSE
dx = -step
ENDIF
ENDIF
IF POINT(x4,y9) = winColor THEN
home1[]
IF distance < maxDistancePerPath THEN
ADD score, maxDistancePerPath - distance
CENTER "+"+STR(maxDistancePerPath - distance)+" points!"
ELSE
CENTER "no points!"
ENDIF
clrline1[]
dy = 0
dx = 0
y = 8
x = startPosX
DEC currentballs
ELSEIF y > screenLimitBH THEN
home1[]
CENTER "missed!"
clrline1[]
dy = 0
dx = 0
y = 8
x = startPosX
DEC currentballs
ELSEIF x >= screenLimitBW AND dx > 0 THEN
dx = -step
ELSEIF x < step AND dx < 0 THEN
dx = step
ELSEIF POINT(x9,y4) <> BLACK THEN
dx = -step
ELSEIF POINT(x3,y4) <> BLACK THEN
dx = step
ENDIF
ENDIF
ADD x, dx
ADD y, dy
INC distance
ENDIF
m = 1
d = 1
UNTIL y > SCREEN HEIGHT
END PROCEDURE
PROCEDURE waitRaster
WAIT WHILE m
FORBID
WHILE RASTER LINE < y+16
WEND
ALLOW
END PROC
PARALLEL PROCEDURE drawBalls
DO
waitRaster[]
d = 1
IF px <> x OR py <> y THEN
PUT IMAGE bgball FRAME i AT px, py
GET IMAGE bgball FRAME i FROM x, y
PUT IMAGE ball AT x, y WITH TRANSPARENCY
px = x
py = y
ENDIF
d = 0
LOOP
END PROCEDURE
PARALLEL PROCEDURE movePlayerAndDrawScore
DO
INK GREY
IF oldscore <> score THEN
HOME
PRINT score
oldscore = score
ENDIF
IF oldballs <> currentballs THEN
LOCATE currentBallsX, 0: PRINT "BALLS: "; currentballs;" "
oldballs = currentballs
ENDIF
IF y = 8 THEN
IF ( JLEFT(0) OR KEY PRESSED(KEY A) ) AND x > screenLimitL THEN
ADD x, -step
ENDIF
IF ( JRIGHT(0) OR KEY PRESSED(KEY D) ) AND x < screenLimitBW THEN
ADD x, step
ENDIF
IF JFIRE(0) OR KEY PRESSED(KEY SPACE) THEN
dy = 1
INC y
distance = 0
ENDIF
ENDIF
LOOP
END PROC
prepareGraphics[]
DO
titleScreen[]
currentballs = maxBallPerGame
oldscore = -1
score = 0
y = 8
x = startPosX
dx = 0
dy = 0
d = 1
m = 0
drawBarriersAndBaskets[]
tmb = SPAWN moveBall
tdb = SPAWN drawBalls
tmp = SPAWN movePlayerAndDrawScore
DO
EXIT IF currentballs = 0
RUN PARALLEL
LOOP
KILL tmb
KILL tdb
KILL tmp
center[]
CENTER "{RED}score: "+STR(score)
PRINT
CENTER "(press fire)"
WAIT KEY OR FIRE RELEASE
LOOP
SOURCE FILE
HOW TO COMPILE AND RUN
The instructions here refer to compiling the example from the command line. For Microsoft Windows users we suggest using UGBASIC-IDE, which allows you to compile the example with just one click.
ATARI 400/800 family
In order to compile and run the example, you need to have the Altirra emulator, and in particular that the altirra executable is accessible.
Then, type this command on the command line:
# Linux ugbc.atari contrib_gamex.bas -o example.xex altirra example.xex # Windows ugbc.atari.exe contrib_gamex.bas -o example.xex altirra example.xex
ATARI 600XL/800XL/1200XL/XG(SE) family
In order to compile and run the example, you need to have the Altirra emulator, and in particular that the altirra executable is accessible.
Then, type this command on the command line:
# Linux ugbc.atarixl contrib_gamex.bas -o example.xex altirra example.xex # Windows ugbc.atarixl.exe contrib_gamex.bas -o example.xex altirra example.xex
Commodore 64
In order to compile and run the example, you need to have the VICE emulator, and in particular that the x64sc executable is accessible.
Then, type this command on the command line:
# Linux ugbc.c64 contrib_gamex.bas -o example.prg x64sc example.prg # Windows ugbc.c64.exe contrib_gamex.bas -o example.prg x64sc example.prg
Commodore PLUS/4
Using YAPE
In order to run the example, you need to have the YAPE emulator. In particular that the yape executable is accessible.
Then, type this command on the command line:
# Linux ugbc.plus4 contrib_gamex.bas -o example.prg yape example.prg # Windows ugbc.plus4.exe contrib_gamex.bas -o example.prg yape example.prg
Using VICE
In order to run the example, you need to have the VICE emulator. In particular that the xplus4 executable is accessible.
Then, type this command on the command line:
# Linux ugbc.plus4 contrib_gamex.bas -o example.prg xplus4 example.prg # Windows ugbc.plus4.exe contrib_gamex.bas -o example.prg xplus4 example.prg
Dragon 32
In order to compile and run the example, you need to have the XROAR emulator, and in particular that the xroar executable is accessible.
Then, type this command on the command line:
# Linux ugbc.d32 contrib_gamex.bas -o example.bin xroar -rompath (your rom path) example.bin # Windows ugbc.d32.exe contrib_gamex.bas -o example.bin xroar.exe -rompath (your rom path) example.bin
Dragon 64
In order to compile and run the example, you need to have the XROAR emulator, and in particular that the xroar executable is accessible.
Then, type this command on the command line:
# Linux ugbc.d64 contrib_gamex.bas -o example.bin xroar -rompath (your rom path) example.bin # Windows ugbc.d64.exe contrib_gamex.bas -o example.bin xroar.exe -rompath (your rom path) example.bin
PC128 Olivetti Prodest
In order to compile and run the example, you need to have the DCMOTO emulator, and in particular that the dcmoto executable is accessible.
Then, type this command on the command line and on the emulator:
# Linux ugbc.pc128op contrib_gamex.bas -o example.k7 dcmoto (choose BASIC 128) CLEAR,&H2FFF: LOADM"CASS:",R: EXEC # Windows ugbc.pc128op.exe contrib_gamex.bas -o example.k7 dcmoto (choose example.k7) (choose BASIC 128) CLEAR,&H2FFF: LOADM"CASS:",R: EXEC
Thomson MO5
In order to compile and run the example, you need to have the DCMOTO emulator, and in particular that the dcmoto executable is accessible.
Then, type this command on the command line and on the emulator:
# Linux ugbc.pc128op contrib_gamex.bas -o example.k7 dcmoto (choose BASIC 128) CLEAR,&H2FFF: LOADM"CASS:",R: EXEC # Windows ugbc.pc128op.exe contrib_gamex.bas -o example.k7 dcmoto (choose example.k7) (choose BASIC 128) CLEAR,&H2FFF: LOADM"CASS:",R: EXEC
Commodore VIC-20
In order to compile and run the example, you need to have the VICE emulator, and in particular that the xvic executable is accessible.
Then, type this command on the command line:
# Linux ugbc.vic20 contrib_gamex.bas -o example.prg xvic --memory 24k example.prg # Windows ugbc.vic20.exe contrib_gamex.bas -o example.prg xvic --memory 24k example.prg
ZX Spectrum
In order to compile and run the example, you need to have the Speccy emulator, and in particular that the speccy executable is accessible.
Then, type this command on the command line:
# Linux ugbc.zx contrib_gamex.bas -o example.tap Speccy example.tap # Windows ugbc.zx.exe contrib_gamex.bas -o example.tap Speccy example.tap
MSX
In order to compile and run the example, you need to have the openMsx or the BlueMSX emulator, and in particular that its executable is accessible.
Then, type this command on the command line:
openMSX
# Linux ugbc.msx1 contrib_gamex.bas -o example.rom openmsx -cart example.rom # Windows ugbc.msx1.exe contrib_gamex.bas -o example.rom openmsx -cart example.rom
blueMSX
# Linux ugbc.msx1 contrib_gamex.bas -o example.rom bluemsx example.rom # Windows ugbc.msx1.exe contrib_gamex.bas -o example.rom bluemsx example.rom
ColecoVision
In order to compile and run the example, you need to have the openMsx or the BlueMSX emulator, and in particular that its executable is accessible.
Then, type this command on the command line:
openMSX
# Linux ugbc.coleco contrib_gamex.bas -o example.rom openmsx -machine \"COL - ColecoVision\" -cart example.rom # Windows ugbc.coleco.exe contrib_gamex.bas -o example.rom bluemsx -machine \"COL - ColecoVision\" example.rom
blueMSX
# Linux ugbc.coleco contrib_gamex.bas -o example.rom bluemsx /machine \"COL - ColecoVision\" /rom1 example.rom # Windows ugbc.coleco.exe contrib_gamex.bas -o example.rom bluemsx /machine \"COL - ColecoVision\" /rom1 example.rom
SEGA SC-3000
In order to compile and run the example, you need to have the BlueMSX emulator, and in particular that its executable is accessible.
Then, type this command on the command line:
# Linux ugbc.sc3000 contrib_gamex.bas -o example.rom bluemsx /machine \"SEGA - SC-3000\" /rom1 example.rom # Windows ugbc.sc3000.exe contrib_gamex.bas -o example.rom bluemsx /machine \"SEGA - SC-3000\" /rom1 example.rom
SEGA SG-1000
In order to compile and run the example, you need to have the BlueMSX emulator, and in particular that its executable is accessible.
Then, type this command on the command line:
# Linux ugbc.sg1000 contrib_gamex.bas -o example.rom bluemsx /machine \"SEGA - SG-1000\" /rom1 example.rom # Windows ugbc.sg1000.exe contrib_gamex.bas -o example.rom bluemsx /machine \"SEGA - SG-1000\" /rom1 example.rom
ANY PROBLEM?
If you have found a problem trying to run this example, if you think there is a bug or, more simply, you would like it to be improved, open an issue for this example on GitHub. Thank you!
POWERED BY
