ugBASIC Manuale Utente
SCOPO
SORGENTE
DEFINE STRING SPACE 128
DEFINE STRING COUNT 32
DEFINE SCREEN MODE UNIQUE
BITMAP ENABLE(16)
CONST step = 2
CONST levels = SCREEN HEIGHT / 16
CONST screenLimitH = ( SCREEN HEIGHT - 1 )
CONST screenLimitH2 = screenLimitH - 16
CONST screenLimitW = ( SCREEN WIDTH - 1 )
CONST screenLimitBH = ( SCREEN HEIGHT - 12 )
CONST screenLimitBW = ( SCREEN WIDTH - 8 )
CONST screenLimitBWB = ( SCREEN WIDTH - 16 )
CONST screenLimitL = 2*step
CONST maxDistancePerPath = 300
CONST startPosX = ( SCREEN WIDTH / 2 ) - 4
CONST maxBallPerGame = 10
CONST centerScreenY = SCREEN ROWS / 2
CONST currentBallsX = SCREEN COLUMNS - 10
DIM x%, y%, px%, py%, dx%, dy%, d@, m@, v@, currentballs@, oldballs@, winColor@
DIM score%, oldscore%,distance%, bx%, by%
GLOBAL x, y, px, py, f, dx, dy, d, m, v, score, oldscore, currentballs, oldballs, distance
GLOBAL winColor, blockColor
GLOBAL bx, by
GLOBAL ball, bar, bgball
GLOBAL basket
PROCEDURE home1
LOCATE , 1
END PROCEDURE
PROCEDURE clrline1
WAIT 1000 MS
LOCATE ,1: CENTER " "
END PROCEDURE
PROCEDURE center
LOCATE , centerScreenY
END PROCEDURE
PROCEDURE titleScreen
CLS
LOCATE , centerScreenY
INK BLUE
CENTER "{BLUE}10 BALLS DOWN!"
CENTER "{GREY}(press fire)"
PRINT
CENTER "{RED}last score: "+STR(score)
WAIT KEY OR FIRE RELEASE
END PROCEDURE
PROCEDURE prepareGraphics
bgball := NEW IMAGE(16,10)
CLS BLACK
INK GREY
BAR 0,0 TO 15,3
INK BLUE
DRAW"L16R2U3L2R16L2D3L4U3L3D3"
bar := NEW IMAGE(16,4)
GET IMAGE bar FROM 0, 0
CLS
INK GREY
BAR 0,0 TO 15,7
INK BLUE
DRAW"BU8D8L15U8"
basket := NEW IMAGE(16,8)
GET IMAGE basket FROM 0, 0
winColor = POINT(3,1)
CLS
INK RED
CIRCLE 4,4,4
PAINT(4,4)
INK WHITE
DRAW"BU2L1D1L1D1"
ball := NEW IMAGE(16,10)
GET IMAGE ball FROM 0, 0
CLS
GET IMAGE bgball FROM 0, 0
END PROCEDURE
PROCEDURE drawBarrier
bx = 0
j = RND(255): i = j: c = 0
REPEAT
IF (j AND 1) = 1 THEN
PUT IMAGE bar AT bx, by
INC c
ENDIF
j = j \ 2
IF ( j = 0 AND c > 4 ) THEN
j = i AND 127
ENDIF
ADD bx, 16
UNTIL bx > screenLimitBW
END PROCEDURE
PROCEDURE drawBarriersAndBaskets
CLS
RANDOMIZE TIMER
by = 24
REPEAT
drawBarrier[]
ADD by, 16
UNTIL by > screenLimitH2
bx = 8
REPEAT
PUT IMAGE basket AT bx, by
ADD bx, RND(16)
ADD bx, 20
UNTIL bx > screenLimitBWB
INK BLUE
DRAW 0,16 TO 0,screenLimitH
DRAW 0,screenLimitH TO screenLimitW,screenLimitH
DRAW screenLimitW,16 TO screenLimitW,screenLimitH
END PROCEDURE
PARALLEL PROCEDURE moveBall
REPEAT
WAIT WHILE d
IF dy OR dx THEN
x3 = x-3: x4 = x+4: y9 = y+9
x9 = x+9: y4 = y+4
IF POINT(x4,y9) = BLACK THEN
dy = 1
dx = 0
ELSE
dy = 0
IF dx = 0 AND y < screenLimitBH THEN
IF RND(100) > 50 THEN
dx = step
ELSE
dx = -step
ENDIF
ENDIF
IF POINT(x4,y9) = winColor THEN
home1[]
IF distance < maxDistancePerPath THEN
ADD score, maxDistancePerPath - distance
CENTER "+"+STR(maxDistancePerPath - distance)+" points!"
ELSE
CENTER "no points!"
ENDIF
clrline1[]
dy = 0
dx = 0
y = 8
x = startPosX
DEC currentballs
ELSEIF y > screenLimitBH THEN
home1[]
CENTER "missed!"
clrline1[]
dy = 0
dx = 0
y = 8
x = startPosX
DEC currentballs
ELSEIF x >= screenLimitBW AND dx > 0 THEN
dx = -step
ELSEIF x < step AND dx < 0 THEN
dx = step
ELSEIF POINT(x9,y4) <> BLACK THEN
dx = -step
ELSEIF POINT(x3,y4) <> BLACK THEN
dx = step
ENDIF
ENDIF
ADD x, dx
ADD y, dy
INC distance
ENDIF
m = 1
d = 1
UNTIL y > SCREEN HEIGHT
END PROCEDURE
PROCEDURE waitRaster
WAIT WHILE m
FORBID
WHILE RASTER LINE < y+16
WEND
ALLOW
END PROC
PARALLEL PROCEDURE drawBalls
DO
waitRaster[]
d = 1
IF px <> x OR py <> y THEN
PUT IMAGE bgball FRAME i AT px, py
GET IMAGE bgball FRAME i FROM x, y
PUT IMAGE ball AT x, y WITH TRANSPARENCY
px = x
py = y
ENDIF
d = 0
LOOP
END PROCEDURE
PARALLEL PROCEDURE movePlayerAndDrawScore
DO
INK GREY
IF oldscore <> score THEN
HOME
PRINT score
oldscore = score
ENDIF
IF oldballs <> currentballs THEN
LOCATE currentBallsX, 0: PRINT "BALLS: "; currentballs;" "
oldballs = currentballs
ENDIF
IF y = 8 THEN
IF ( JLEFT(0) OR KEY PRESSED(KEY A) ) AND x > screenLimitL THEN
ADD x, -step
ENDIF
IF ( JRIGHT(0) OR KEY PRESSED(KEY D) ) AND x < screenLimitBW THEN
ADD x, step
ENDIF
IF JFIRE(0) OR KEY PRESSED(KEY SPACE) THEN
dy = 1
INC y
distance = 0
ENDIF
ENDIF
LOOP
END PROC
prepareGraphics[]
DO
titleScreen[]
currentballs = maxBallPerGame
oldscore = -1
score = 0
y = 8
x = startPosX
dx = 0
dy = 0
d = 1
m = 0
drawBarriersAndBaskets[]
tmb = SPAWN moveBall
tdb = SPAWN drawBalls
tmp = SPAWN movePlayerAndDrawScore
DO
EXIT IF currentballs = 0
RUN PARALLEL
LOOP
KILL tmb
KILL tdb
KILL tmp
center[]
CENTER "{RED}score: "+STR(score)
PRINT
CENTER "(press fire)"
WAIT KEY OR FIRE RELEASE
LOOP
FILE
COME ESEGUIRLO
Atari 400/800
Per poter eseguire l'esempio, è necessario disporre dell'emulatore Altirra, e in particolare che l'eseguibile x64sc sia accessibile.
Digitare quindi il seguente comando:
# Linux ugbc.atari contrib_gamex.bas -o example.xex altirra example.xex # Windows ugbc.atari.exe contrib_gamex.bas -o example.xex altirra example.xex
Atari 600XL/800XL/1200XL/XG(SE)
Per poter eseguire l'esempio, è necessario disporre dell'emulatore Altirra, e in particolare che l'eseguibile x64sc sia accessibile.
Digitare quindi il seguente comando:
# Linux ugbc.atarixl contrib_gamex.bas -o example.xex altirra example.xex # Windows ugbc.atarixl.exe contrib_gamex.bas -o example.xex altirra example.xex
Commodore 64
Per poter eseguire l'esempio, è necessario disporre dell'emulatore VICE, e in particolare che l'eseguibile x64sc sia accessibile.
Digitare quindi il seguente comando:
# Linux ugbc.c64 contrib_gamex.bas -o example.prg x64sc example.prg # Windows ugbc.c64.exe contrib_gamex.bas -o example.prg x64sc example.prg
Commodore PLUS/4
Usando YAPE
Per poter eseguire l'esempio, è necessario disporre dell'emulatore YAPE, e in particolare che l'eseguibile yape sia accessibile.
Digitare quindi il seguente comando:
# Linux ugbc.plus4 contrib_gamex.bas -o example.prg yape example.prg # Windows ugbc.plus4.exe contrib_gamex.bas -o example.prg yape example.prg
Usando VICE
Per poter eseguire l'esempio, è necessario disporre dell'emulatore VICE, e in particolare che l'eseguibile xplus4 sia accessibile.
Digitare quindi il seguente comando:
# Linux ugbc.plus4 contrib_gamex.bas -o example.prg xplus4 example.prg # Windows ugbc.plus4.exe contrib_gamex.bas -o example.prg xplus4 example.prg
Dragon 32
Per poter eseguire l'esempio, è necessario disporre dell'emulatore XROAR, e in particolare che l'eseguibile x64sc sia accessibile.
Digitare quindi il seguente comando:
# Linux ugbc.d32 contrib_gamex.bas -o example.bin xroar -rompath (percorso ROM) example.bin # Windows ugbc.d32.exe contrib_gamex.bas -o example.bin xroar.exe -rompath (percorso ROM) example.bin
Dragon 64
Per poter eseguire l'esempio, è necessario disporre dell'emulatore XROAR, e in particolare che l'eseguibile x64sc sia accessibile.
Digitare quindi il seguente comando:
# Linux ugbc.d64 contrib_gamex.bas -o example.bin xroar -rompath (percorso ROM) example.bin # Windows ugbc.d64.exe contrib_gamex.bas -o example.bin xroar.exe -rompath (percorso ROM) example.bin
PC128 Olivetti Prodest
Per poter eseguire l'esempio, è necessario disporre dell'emulatore DCMOTO, e in particolare che l'eseguibile x64sc sia accessibile.
Digitare quindi i seguenti comandi:
# Linux ugbc.pc128op contrib_gamex.bas -o example.bin dcmoto example.bin (scegliere example.bin) (scegliere BASIC 128) CLEAR,&H2FFF: LOADM"CASS:",R: EXEC # Windows ugbc.pc128op.exe contrib_gamex.bas -o example.bin dcmoto example.bin (scegliere BASIC 128) CLEAR,&H2FFF: LOADM"CASS:",R: EXEC
Thomson MO5
Per poter eseguire l'esempio, è necessario disporre dell'emulatore DCMOTO, e in particolare che l'eseguibile x64sc sia accessibile.
Digitare quindi i seguenti comandi:
# Linux ugbc.mo5 contrib_gamex.bas -o example.bin dcmoto example.bin (scegliere example.bin) (scegliere BASIC 128) CLEAR,&H2FFF: LOADM"CASS:",R: EXEC # Windows ugbc.mo5.exe contrib_gamex.bas -o example.bin dcmoto example.bin (scegliere BASIC 128) CLEAR,&H2FFF: LOADM"CASS:",R: EXEC
Commodore VIC-20
Per poter eseguire l'esempio, è necessario disporre dell'emulatore XEMU, e in particolare che l'eseguibile xmega65 sia accessibile.
Digitare quindi il seguente comando:
# Linux ugbc.vic20 contrib_gamex.bas -o example.prg xvic --memory 24k example.prg # Windows ugbc.vic20.exe contrib_gamex.bas -o example.prg xvic --memory 24k example.prg
ZX Spectrum
Per poter eseguire l'esempio, è necessario disporre dell'emulatore Speccy, e in particolare che l'eseguibile speccy sia accessibile.
Digitare quindi il seguente comando:
# Linux ugbc.zx contrib_gamex.bas -o example.tap Speccy example.tap # Windows ugbc.zx.exe contrib_gamex.bas -o example.tap Speccy example.tap
ColecoVision
Per compilare e mandare in esecuzione l'esempio, hai bisogno di avere l'emulatore openMsx oppure il BlueMSX, e in particolare che il suo eseguibile sia accessibile.
Dopo di che, digita questo comando sulla linea di comando:
openMSX
# Linux ugbc.coleco contrib_gamex.bas -o example.rom openmsx -machine \"COL - ColecoVision\" -cart example.rom # Windows ugbc.coleco.exe contrib_gamex.bas -o example.rom bluemsx -machine \"COL - ColecoVision\" example.rom
blueMSX
# Linux ugbc.coleco contrib_gamex.bas -o example.rom bluemsx /machine \"COL - ColecoVision\" /rom1 example.rom # Windows ugbc.coleco.exe contrib_gamex.bas -o example.rom bluemsx /machine \"COL - ColecoVision\" /rom1 example.rom
SEGA SC-3000
Per compilare e mandare in esecuzione l'esempio, hai bisogno di avere l'emulatore BlueMSX, e in particolare che il suo eseguibile sia accessibile.
Dopo di che, digita questo comando sulla linea di comando:
# Linux ugbc.sc3000 contrib_gamex.bas -o example.rom bluemsx /machine \"SEGA - SC-3000\" /rom1 example.rom # Windows ugbc.sc3000.exe contrib_gamex.bas -o example.rom bluemsx /machine \"SEGA - SC-3000\" /rom1 example.rom
SEGA SG-1000
Per compilare e mandare in esecuzione l'esempio, hai bisogno di avere l'emulatore BlueMSX, e in particolare che il suo eseguibile sia accessibile.
Dopo di che, digita questo comando sulla linea di comando:
# Linux ugbc.sg1000 contrib_gamex.bas -o example.rom bluemsx /machine \"SEGA - SG-1000\" /rom1 example.rom # Windows ugbc.sg1000.exe contrib_gamex.bas -o example.rom bluemsx /machine \"SEGA - SG-1000\" /rom1 example.rom
PROBLEMI?
Se hai trovato un problema nel cercare di eseguire questo esempio, se pensi che ci sia un bug o, più semplicemente, vorresti che fosse migliorato, apri una segnalazione su GitHub per questo specifico esempio. Grazie!
POWERED BY
